Aliases

mIRC permet de créer des alias et des scripts pour accélérer votre session IRC ou pour exécuter des commandes plus simplement. Pour créer des alias vous devez connaître les Commandes IRC.

Les alias peuvent être appelés de la ligne de commande, depuis d'autres alias, de menus popups et de scripts remote. Un alias ne peut s'appeler par lui-même récursivement, parce que ceci cause des problèmes aux usagers. Exemples
Les exemples suivants montrent comment créer des alias performant des fonctions simples. /sdb /join #scriptsdb.org Si vous tapez /sdb ceci équivaut à taper /join #scriptsdb.org. /j /join #$1 Maintenant nous avons ajouté un string avec paramètres. Si on tape /j #scriptsdb.org, ceci équivaut à taper /join #scriptsdb.org. Le $1 réfère au premier paramètre dans la ligne que vous donnez. /dire /me $2 $1 Si vous tapez /dire Toi! Salut la commande sera /me Salut Toi!. Le nombre après le $ spécifie le numéro du paramètre dans la commande que vous entrez. /jj /join $? Le point d'interrogation indique que vous allez être demandé pour remplir le paramètre. Le paramètre que vous allez donner sera inséré dans la ligne à ce point. alors si vous tapez /jj, un dialog apparaîtra vous demandant le canal à joindre. Si vous entrez #scriptsdb.org, alors la commande finale sera /join #scriptsdb.org. /jj /join #$1 Le signe # indique que le paramètre devra être précédé du signe indiquant que c'est un canal. /jj /join $?="Entrez un canal:" Ceci fait la même chose, sauf que cette fois le dialog contiendra la ligne "Entrez un canal:" d'affiché à l'intérieur. /aw /away $?="Message Away:" | /say $! Ceci est similaire à la ligne auparavant à l'exception de l'addition du paramètre $!. Ceci réfère à ce que vous venez juste de taper dans la boîte de paramètre i.e. le message d'away. Ceci vous évite d'avoir à l'écrire 2 fois de suite. /donne /me donne $$1 à $$2 Le double $$ signifie que la commande sera exécuté seulement si un paramètre est spécifié. Si vous ne spécifier qu'un seul paramètre avec la commande ci-haut, elle ne sera pas exécuté. Vous pouvez aussi utiliser $$?1 ou $?1 ce qui veut dire d'essayer de remplir la valeur avec le paramètre un s'il existe. Si le paramètre un n'existe pas, alors le demander. Dans le premier cas, le paramètre est nécessaire pour que la commande soit exécuté, dans le second ce n'est pas le cas. /slap /me frappe $1 avec $2- Le $2- indique tout ce qui suit incluant le paramètre 2 devrait être pris dans la ligne de commande. Si vous tapez /slap ClickHeRe une pelle, la ligne finale serait /me frappe ClickHeRe avec une pelle. Vous pouvez aussi spécifier $2-5 qui veut dire d'utiliser les paramètres 2 à 5 seulement. /rire /me laughs at $1's joke N'importe quoi rattaché à un paramètre $ sera inclut dans le paramètre final. Par exemple si vous tapez /rire ClickHeRe, la commande finale sera /me laughs at ClickHeRe's joke. /rien /say Sal $+ ut To $+ i! Les paramètres sont normalement séparés par des espaces. Pour faire en sorte que mIRCcombine les paramètres vous pouvez utiliser l'identifieur $+. La ligne ci-haut va dire Salut Toi!. /p /part # Le signe # réfère au canal sur lequel vous êtes présentement. Si vous êtes sur le canal #bleh, et que vous tapez /p alors le client remplace la valeur de # par #bleh et la commande finale est /part #bleh. /op /mode # +o $1 Pour donner le status de op à quelqu'un vous n'avez qu'à taper /op nick au lieu de taper toute la commande /mode. /deop /mode # -ooo $1 $2 $3 Avec cette commande vous pouvez déopper 3 personnes à la fois en tapant /deop nick1 nick2 nick3.

Pour des commandes multiples vous devriez utiliser le caractère | (le caractère \ + shift). Alors pour créer un alias qui kick et banni quelqu'un: /kb /kick # $1 | /mode # +b $1Les crochets d'évaluation [ ]
Si vous voulez un plus grand contrôle sur l'ordre d'évaluation des identifieurs, vous pouvez utiliser les Crochets []. Les identifieurs situés entre des crochets sont évalués les premiers de gauche vers la droite. Vous pouvez avoir des niveaux multiples de crochets. /say % [ $+ [ $1]] Vous pouvez aussi forcer un identifieur évalué plus tôt à être réévalué en rajoutant une deuxième paire de [].
/set %x %y
/set %y Hiya!
/echo [ [ %x ] ] 
Les accolades { }
Vous pouvez créer plusieurs scripts multi-lignes en utilisant les accolades { }. Ceci permet de créer un alias qui perform plusieurs commandes.
salut {
  /say Salut
  /say $1
}
L'expression If-then-else
Vous pouvez utiliser l'expression if-then-else pour décider des parties de votre script à être exécuté basé sur des comparaisons.
/nombre {
  if ($1 == 1) echo Nombre UN
  elseif ($1 == 2) echo Nombre DEUX
  else echo Nombre Inconnu!
}
Ceci crée un alias qui compare le paramètre que vous donnez avec les nombres 1 ou 2.

Pour plus d'informations, vois la section if-then-else. La commande Goto
La commande /goto permet de sauter d'un point à un autre dans un script.
/nombre {
  if ($1 == 1) goto one
  elseif ($1 == 2) goto two
  else goto unknown
  :one
  echo Nombre UN
  halt
  :two
  echo Nombre DEUX
  halt
  :unknown
  echo Nombre Inconnu!
  halt
}
La mauvaise utilisation d'un goto pourrait se transformer en une boucle infinie. Vous pouvez sortir d'un script actuellement en traitement avec la combinaison Control-Break. Note: Les commandes ci-haut n'ont pas de préfix /. Ceci est seulement nécessaire lorsque vous entrez une commande sur la ligne de commande. Dans tous les scripts, toutes les lignes sont assumées comme étant le début d'une commande, alors vous n'avez pas besoin du préfix de commande /. Les Boucles While
Répète une boucle de commandes tant que l'expression dans les paranthèses est vraie.
var %i = 1
while (%i <= 10) {
  echo 2 %i
  inc %i
}
L'expression dans les paranthèses suivent les même règles que le If-Then-Else.

De multiples boucles peuvent être imbriqués. Vous pouvez utiliser la commande /break pour sortir de la boucle courante, et /continue pour faire un saut au début de la boucle. La commande Return
La commande /return arrête un script actuellement en cours de traitement et permet à la routine appelante de continuer son traitement. Vous pouvez aussi spécifier une valeur de retour optionnelle qui retrouvera dans l'identifieur $result. Le $result peut être utilisé dans une routine appelante. /return [valeur]La commande Halt
La commande /halt arrête un script et le traitement futur. Vous pouvez aussi l'utiliser dans un Script Remote pour prévenir l'affichage par mIRC de messages ctcp normaux, ou dans des alias pour arrêter l'alias, ou n'importe quel routine complètement. Identifieurs et Variables
Un identifieur retourne la valeur d'une variable du code source de mIRC. Par exemple, $time retourne le temps courant. Lorsque mIRC trouve un identifieur dans votre commande, il le remplace par la valeur courante de cet identifieur. Pour une liste des identifieurs, voir la section Identifieurs. Les variables sont des identifieurs dont vous pouvez créer la valeur et la changer plus tard et les utilisez ultérieurement dans vos scripts. Pour plus d'informations sur les variables, voir la section Variables. Identifieurs Personnalisés
Un identifieur personnalisé est simplement un alias qui retourne une valeur, et vous pouvez utiliser le nom de cet alias avec le préfix d'un identifieur.

Par exemple, pour créer un alias /add comme:
add {
  %x = $1 + $2
  return %x
}
Et ensuite utilisez la commande: //echo Total est: $add(1,2) Vous pouvez fournir autant de paramètres que vous voulez à un identifieur e. g. $add(1,2,...,N). Vous pouvez également utiliser l'identifieur $prop pour référer à vos attributs personnalisées:
add {
  %x = $1 + $2
  if ($prop == negative) return $calc(-1 * %x)
  return %x
}
//echo Total is: $add(1,2).negativeNote: Les identifieurs construits dans mIRC ayant le même nom ont priorité. Scripts Remote
Vous pouvez ajouter des alias dans les scripts remote en utilisant le préfix alias et ensuite en entrant votre alias à la main.
alias add {
  %x = $1 + $2
  return %x
}
Ceci est le même identifieur personnel que plus tôt, sauf qu'il utilise le préfix alias. Si vous spécifiez l'option -l dans la définition, alors l'alias devient accessible seulement par des commandes du même script et invisible à la ligne de commande et aux autres scripts.
alias -l add {
  %x = $1 + $2
  return %x
}
Support de Touches
Vous pouvez redéfinir les touches de contrôle pour performer certaines commandes, comme des alias. Par exemple:
/F1 /say Hello!
/sF2 /query $1
/cF3 /ctcp $1 version 
Les préfixes s et c sont pour les touches Shift et Control respectivement. Note: Une touche de fonction va réagir différemment selon la fenêtre où elle est utilisé. Par exemple, quand vous êtes dans une fenêtre privée le paramètre $1 réfère au nick de l'usager. Si vous êtes sur un canal et que la liste de nicks est active, alors la touche va fonctionner sur les nicks sélectionnés. Si la liste n'est pas active, la touche va fonctionner sur le canal seulement. Préfixes de Commandes
Si vous exécutez une commande de la ligne de commande i.e. en tapant dans la boîte de texte, vous pouvez forcermIRC à évaluer les identifieurs dans la commande en la précédant de deux // au lieu d'un seul /. Par exemple: /echo Mon nick est $me Afficherait "Mon nick est $me" et n'évaluerait pas $me. //echo Mon nick est $me Afficherait "Mon nick est ClickHeRe" si votre nick est ClickHeRe. Si vous voulez forcer une commande à être exécuté silencieusement i.e. sans l'affichage d'aucune information, vous pouvez utiliser un "." devant la commande. Par exemple: /ignore un_nick Afficherait une information du type "you are now ignoring un_nick". Si vous ne voulez pas voir cet information, alors vous utiliseriez: /.ignore un_nick Si vous voulez faire une commande sans qu'elle soit perçue comme un alias, vous n'avez qu'à la faire précéder d'un !. Commentaires
Vous pouvez ajouter des commentaires à vos scripts en utilisant le ; point-virgule au début de la ligne ou inclure le commentaire entre une paire de /* et */. ; Ceci est un commentaire
/*
Ceci est un commentaire
*/ 
Vous pouvez placer des commentaires n'importe où dans un script car ils sont ignorés dans le traitement. L'identifieur $&
L'identifieur permet de briser une ligne en plusieurs morceaux qui sont combinés lorsque le script est exécuté, alors vous pouvez éditer des longues commandes plus facilement.
longueligne {
  echo Ceci est une $&
  très très très $&
  longue ligne de texte
}